diff mbox series

[meta-gnome,1/2] gnome-remote-desktop: add recipe

Message ID 20230823124645.6878-1-f_l_k@t-online.de
State Under Review
Headers show
Series [meta-gnome,1/2] gnome-remote-desktop: add recipe | expand

Commit Message

Markus Volk Aug. 23, 2023, 12:46 p.m. UTC 
- use dynamic-layers directory because this recipe depends on meta-virtualization

Signed-off-by: Markus Volk <f_l_k@t-online.de>
---
 meta-gnome/conf/layer.conf                    |  4 ++
 .../gnome-remote-desktop_44.2.bb              | 38 +++++++++++++++++++
 2 files changed, 42 insertions(+)
 create mode 100644 meta-gnome/dynamic-layers/meta-virtualization/recipes-gnome/gnome-remote-desktop/gnome-remote-desktop_44.2.bb
diff mbox series

Patch

diff --git a/meta-gnome/conf/layer.conf b/meta-gnome/conf/layer.conf
index d7286edab5..324d8b8c6e 100644
--- a/meta-gnome/conf/layer.conf
+++ b/meta-gnome/conf/layer.conf
@@ -24,3 +24,7 @@  SIGGEN_EXCLUDE_SAFE_RECIPE_DEPS += "\
   faenza-icon-theme->gtk+3 \
 "
 
+BBFILES_DYNAMIC += " \
+    virtualization-layer:${LAYERDIR}/dynamic-layers/meta-virtualization/*/*/*.bb \
+    virtualization-layer:${LAYERDIR}/dynamic-layers/meta-virtualization/*/*/*.bbappend \
+"
diff --git a/meta-gnome/dynamic-layers/meta-virtualization/recipes-gnome/gnome-remote-desktop/gnome-remote-desktop_44.2.bb b/meta-gnome/dynamic-layers/meta-virtualization/recipes-gnome/gnome-remote-desktop/gnome-remote-desktop_44.2.bb
new file mode 100644
index 0000000000..48e4d9f32f
--- /dev/null
+++ b/meta-gnome/dynamic-layers/meta-virtualization/recipes-gnome/gnome-remote-desktop/gnome-remote-desktop_44.2.bb
@@ -0,0 +1,38 @@ 
+SUMMARY = "Remote desktop daemon for GNOME using pipewire."
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+
+GNOMEBASEBUILDCLASS = "meson"
+
+inherit gnomebase gettext gsettings features_check
+
+REQUIRED_DISTRO_FEATURES = "opengl"
+
+SRC_URI[archive.sha256sum] = "7a9ffd341b5fcb636d26675e9f6269650952163fff5295327618cc2d5cc87b8e"
+
+DEPENDS = " \
+    asciidoc-native \
+    libdrm \
+    libepoxy \
+    cairo \
+    glib-2.0 \
+    pipewire \
+    libnotify \
+    libsecret \
+    nv-codec-headers \
+    tpm2-tss \
+"
+
+PACKAGECONFIG ??= " \
+    vnc \
+    rdp \
+    ${@bb.utils.contains('LICENSE_FLAGS_ACCEPTED', 'commercial', 'fdk_aac', '', d)} \
+    ${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
+"
+
+PACKAGECONFIG[vnc] = "-Dvnc=true,-Dvnc=false,libvncserver"
+PACKAGECONFIG[rdp] = "-Drdp=true,-Drdp=false,freerdp fuse3 libxkbcommon"
+PACKAGECONFIG[fdk_aac] = "-Dfdk_aac=true,-Dfdk_aac=false,fdk-aac"
+PACKAGECONFIG[systemd] = "-Dsystemd=true,-Dsystemd=false,systemd"
+
+FILES:${PN} += "${systemd_user_unitdir}"