diff mbox series

[meta-arago,master/kirkstone,PATCHv2] piglit: add conditional config to point at deqp bins

Message ID 20230622165010.2378146-1-rs@ti.com
State Accepted
Delegated to: Ryan Eatmon
Headers show
Series [meta-arago,master/kirkstone,PATCHv2] piglit: add conditional config to point at deqp bins | expand

Commit Message

Randolph Sapp June 22, 2023, 4:50 p.m. UTC 
From: Randolph Sapp <rs@ti.com>

Add a PACKAGECONFIG to define runtime dependencies on deqp tests and
conditionally set values for the default config so piglit works out of
the box.

Adjust the arago.conf accordingly. Drop the explicit requirements for
individual cts tests in ti-test-extras.

Signed-off-by: Randolph Sapp <rs@ti.com>
---
 meta-arago-distro/conf/distro/arago.conf      |  6 +++-
 .../recipes-core/packagegroups/ti-test.bb     |  2 --
 .../recipes-graphics/piglit/piglit_%.bbappend | 30 +++++++++++++++++++
 3 files changed, 35 insertions(+), 3 deletions(-)
 create mode 100644 meta-arago-distro/recipes-graphics/piglit/piglit_%.bbappend
diff mbox series

Patch

diff --git a/meta-arago-distro/conf/distro/arago.conf b/meta-arago-distro/conf/distro/arago.conf
index f770345c..512bc175 100644
--- a/meta-arago-distro/conf/distro/arago.conf
+++ b/meta-arago-distro/conf/distro/arago.conf
@@ -99,7 +99,11 @@  PACKAGECONFIG:pn-glmark2 = "drm-gles2 wayland-gles2"
 PACKAGECONFIG:pn-weston-init = ""
 
 # Enable testing for opencl and vulkan with piglit
-PACKAGECONFIG:append:pn-piglit = " ${@bb.utils.filter("DISTRO_FEATURES", "opencl vulkan", d)}"
+PACKAGECONFIG:append:pn-piglit = " \
+    ${@bb.utils.filter("DISTRO_FEATURES", "opencl vulkan", d)} \
+    ${@bb.utils.contains("DISTRO_FEATURES", "opengl", "deqp-gles", "", d)} \
+    ${@bb.utils.contains("DISTRO_FEATURES", "vulkan", "deqp-vk", "", d)} \
+"
 PACKAGECONFIG:pn-opengl-es-cts = "${@bb.utils.contains("DISTRO_FEATURES", "wayland", "wayland", "surfaceless", d)}"
 PACKAGECONFIG:pn-vulkan-cts = "${@bb.utils.contains("DISTRO_FEATURES", "wayland", "wayland", "surfaceless", d)}"
 
diff --git a/meta-arago-distro/recipes-core/packagegroups/ti-test.bb b/meta-arago-distro/recipes-core/packagegroups/ti-test.bb
index 793eb583..11c327a0 100644
--- a/meta-arago-distro/recipes-core/packagegroups/ti-test.bb
+++ b/meta-arago-distro/recipes-core/packagegroups/ti-test.bb
@@ -43,8 +43,6 @@  ARAGO_TEST = "\
 ARAGO_TEST_EXTRAS = " \
     python3-numpy \
     piglit \
-    ${@bb.utils.contains("DISTRO_FEATURES", "opengl", "opengl-es-cts", "", d)} \
-    ${@bb.utils.contains("DISTRO_FEATURES", "vulkan", "vulkan-cts", "", d)} \
 "
 
 ARAGO_TEST:append:armv7a = " \
diff --git a/meta-arago-distro/recipes-graphics/piglit/piglit_%.bbappend b/meta-arago-distro/recipes-graphics/piglit/piglit_%.bbappend
new file mode 100644
index 00000000..fb533533
--- /dev/null
+++ b/meta-arago-distro/recipes-graphics/piglit/piglit_%.bbappend
@@ -0,0 +1,30 @@ 
+# add a config to point piglit at the default install location for deqp tests
+# if they are selected
+
+FILESEXTRAPATHS:prepend := "${THISDIR}/${PN}:"
+
+PACKAGECONFIG[deqp-gles] = ",,,opengl-es-cts"
+PACKAGECONFIG[deqp-vk] = ",,,vulkan-cts"
+
+do_install:append() {
+    if ${@bb.utils.contains('PACKAGECONFIG', 'deqp-gles', 'true', 'false', d)}; then
+        printf "%s\n" \
+            "[deqp-egl]" \
+            "bin=/usr/lib/opengl-es-cts/deqp-egl" \
+            "[deqp-gles2]" \
+            "bin=/usr/lib/opengl-es-cts/deqp-gles2" \
+            "[deqp-gles3]" \
+            "bin=/usr/lib/opengl-es-cts/deqp-gles3" \
+            "[deqp-gles31]" \
+            "bin=/usr/lib/opengl-es-cts/deqp-gles31" \
+            >> ${D}/${libdir}/piglit/piglit.conf
+    fi
+    if ${@bb.utils.contains('PACKAGECONFIG', 'deqp-vk', 'true', 'false', d)}; then
+        printf "%s\n" \
+            "[deqp-vk]" \
+            "bin=/usr/lib/vulkan-cts/deqp-vk" \
+            "[deqp-vksc]" \
+            "bin=/usr/lib/vulkan-cts/deqp-vksc" \
+            >> ${D}/${libdir}/piglit/piglit.conf
+    fi
+}