[meta-arm] arm: add TF-A v1.5 recipes

Submitted by Jon Mason on July 31, 2020, 6:06 p.m. | Patch ID: 174966

Details

Message ID 20200731180646.18230-1-jon.mason@arm.com
State New
Headers show

Commit Message

Jon Mason July 31, 2020, 6:06 p.m.
Add trusted-firmware-a recipes for v1.5.  While old, there are platforms
that are still using this older version.

Change-Id: Id40414ad58fd274af86203bb2c8d449e18a10c7a
Signed-off-by: Jon Mason <jon.mason@arm.com>
---
 .../trusted-firmware-a_1.5.bb                 | 32 +++++++++++++++++++
 .../fiptool/fiptool-native_1.5.bb             | 31 ++++++++++++++++++
 2 files changed, 63 insertions(+)
 create mode 100644 meta-arm/recipes-bsp/trusted-firmware-a/trusted-firmware-a_1.5.bb
 create mode 100644 meta-arm/recipes-devtools/fiptool/fiptool-native_1.5.bb

Patch hide | download patch | download mbox

diff --git a/meta-arm/recipes-bsp/trusted-firmware-a/trusted-firmware-a_1.5.bb b/meta-arm/recipes-bsp/trusted-firmware-a/trusted-firmware-a_1.5.bb
new file mode 100644
index 0000000..3570f4c
--- /dev/null
+++ b/meta-arm/recipes-bsp/trusted-firmware-a/trusted-firmware-a_1.5.bb
@@ -0,0 +1,32 @@ 
+#
+# Trusted firmware-A 1.5
+#
+
+require trusted-firmware-a.inc
+
+SRC_URI = "git://git.trustedfirmware.org/TF-A/trusted-firmware-a.git;protocol=https;name=tfa"
+
+# Use TF-A for version
+SRCREV_FORMAT = "tfa"
+
+# TF-A v1.5
+SRCREV_tfa = "ed8112606c54d85781fc8429160883d6310ece32"
+
+S = "${WORKDIR}/git"
+
+LIC_FILES_CHKSUM = "file://license.rst;md5=e927e02bca647e14efd87e9e914b2443"
+
+#
+# mbed TLS source
+# Those are used in trusted-firmware-a.inc if TFA_MBEDTLS is set to 1
+#
+
+SRC_URI_MBEDTLS = "git://github.com/ARMmbed/mbedtls.git;name=mbedtls;protocol=https;destsuffix=git/mbedtls"
+
+# mbed TLS v2.16.2
+SRCREV_mbedtls = "d81c11b8ab61fd5b2da8133aa73c5fe33a0633eb"
+
+LIC_FILES_CHKSUM_MBEDTLS += " \
+    file://mbedtls/apache-2.0.txt;md5=3b83ef96387f14655fc854ddc3c6bd57 \
+    file://mbedtls/LICENSE;md5=302d50a6369f5f22efdb674db908167a \
+    "
diff --git a/meta-arm/recipes-devtools/fiptool/fiptool-native_1.5.bb b/meta-arm/recipes-devtools/fiptool/fiptool-native_1.5.bb
new file mode 100644
index 0000000..925542c
--- /dev/null
+++ b/meta-arm/recipes-devtools/fiptool/fiptool-native_1.5.bb
@@ -0,0 +1,31 @@ 
+# Firmware Image Package (FIP)
+# It is a packaging format used by TF-A to package the
+# firmware images in a single binary.
+
+DESCRIPTION = "fiptool - Trusted Firmware tool for packaging"
+LICENSE = "BSD-3-Clause"
+
+SRC_URI = "git://git.trustedfirmware.org/TF-A/trusted-firmware-a.git;protocol=https"
+LIC_FILES_CHKSUM = "file://license.rst;md5=e927e02bca647e14efd87e9e914b2443"
+
+# Use fiptool from TF-A v1.5
+SRCREV = "ed8112606c54d85781fc8429160883d6310ece32"
+
+DEPENDS += "openssl-native"
+
+inherit native
+
+S = "${WORKDIR}/git"
+
+do_compile () {
+    # These changes are needed to have the fiptool compiling and executing properly
+    sed -i '/^LDLIBS/ s,$, \$\{BUILD_LDFLAGS},' ${S}/tools/fiptool/Makefile
+    sed -i '/^INCLUDE_PATHS/ s,$, \$\{BUILD_CFLAGS},' ${S}/tools/fiptool/Makefile
+
+    oe_runmake fiptool
+}
+
+do_install () {
+    install -d ${D}${bindir}/
+    install -m 0755 tools/fiptool/fiptool ${D}${bindir}
+}