multimedia: janus-gateway: Added new recipe

Added recipe for janus-gateway


Signed-off-by: Marek Belisko <marek.belisko@open-nandra.com>
Signed-off-by: Jake Withecombe <jake@ruggednetworks.co.uk>
---
 .../janus-gateway/files/janus-gateway.service      | 14 +++++++
 .../janus-gateway/janus-gateway_0.7.4.bb           | 48 ++++++++++++++++++++++
 2 files changed, 62 insertions(+)
 create mode 100644 meta-multimedia/recipes-multimedia/janus-gateway/files/janus-gateway.service
 create mode 100644 meta-multimedia/recipes-multimedia/janus-gateway/janus-gateway_0.7.4.bb

On Tue, Dec 10, 2019 at 12:36 PM Marek Belisko
<marek.belisko@open-nandra.com> wrote:
>
> Added recipe for janus-gateway
>
>
> Signed-off-by: Marek Belisko <marek.belisko@open-nandra.com>
> Signed-off-by: Jake Withecombe <jake@ruggednetworks.co.uk>
> ---
>  .../janus-gateway/files/janus-gateway.service      | 14 +++++++
>  .../janus-gateway/janus-gateway_0.7.4.bb           | 48 ++++++++++++++++++++++
>  2 files changed, 62 insertions(+)
>  create mode 100644 meta-multimedia/recipes-multimedia/janus-gateway/files/janus-gateway.service
>  create mode 100644 meta-multimedia/recipes-multimedia/janus-gateway/janus-gateway_0.7.4.bb
>
> diff --git a/meta-multimedia/recipes-multimedia/janus-gateway/files/janus-gateway.service b/meta-multimedia/recipes-multimedia/janus-gateway/files/janus-gateway.service
> new file mode 100644
> index 0000000..5b4d4f2
> --- /dev/null
> +++ b/meta-multimedia/recipes-multimedia/janus-gateway/files/janus-gateway.service
> @@ -0,0 +1,14 @@
> +[Unit]
> +Description=Janus WebRTC Server
> +After=network.target network-online.target
> +Wants=network-online.target
> +
> +[Service]
> +Type=simple
> +ExecStart=/usr/bin/janus -o
> +Restart=always
> +RestartSec=60
> +LimitNOFILE=65536
> +
> +[Install]
> +WantedBy=multi-user.target
> diff --git a/meta-multimedia/recipes-multimedia/janus-gateway/janus-gateway_0.7.4.bb b/meta-multimedia/recipes-multimedia/janus-gateway/janus-gateway_0.7.4.bb
> new file mode 100644
> index 0000000..bca716f
> --- /dev/null
> +++ b/meta-multimedia/recipes-multimedia/janus-gateway/janus-gateway_0.7.4.bb
> @@ -0,0 +1,48 @@
> +DESCRIPTION = "Janus is an open source, general purpose, WebRTC server designed and developed by Meetecho"
> +HOMEPAGE = "https://janus.conf.meetecho.com/"
> +SECTION = "libs/multimedia"
> +
> +LICENSE = "GPLv3"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=c9e0a79f2244c2f79cda22ea5fed9135"
> +
> +SRC_URI = "https://github.com/meetecho/janus-gateway/archive/v${PV}.tar.gz \
> +          file://janus-gateway.service \
> +"
> +
> +SRC_URI[md5sum] = "b068ac2b40ae800d83f471b8189bc87c"
> +SRC_URI[sha256sum] = "01ddaf204203a1219dd46a5ce70b548bab75bc494c9ba05429f8fb1e786b2995"
> +
> +inherit autotools-brokensep pkgconfig systemd
> +
> +DEPENDS = "libsrtp jansson libconfig libnice openssl glib-2.0 gengetopt-native"

gengetopt-native provider is not anywhere in meta-openembedded. So
either make it a packageconfig
and keep it disabled or remove the dependency,

> +
> +PACKAGECONFIG ?= "rest_api rest"
> +#PACKAGECONFIG[disablewarnings] = "--disable-warnings-as-errors,,"
> +#PACKAGECONFIG[inet] = "--enable-inet,--disable-inet,"
> +#PACKAGECONFIG[inet6] = "--enable-inet6,--disable-inet6,"
> +PACKAGECONFIG[rest_api] = "--enable-turn-rest-api,--disable-turn-rest-api,curl"
> +PACKAGECONFIG[rest] = "--enable-rest,--disable-rest,libmicrohttpd"
> +PACKAGECONFIG[unix_sockets] = "--enable-unix-sockets,--disable-unix-sockets,"
> +PACKAGECONFIG[post_processing] = "--enable-post-processing,--disable-post-processing,"
> +PACKAGECONFIG[plugin_echo] = "--enable-plugin-echotest,--disable-plugin-echotest,"
> +PACKAGECONFIG[plugin_videocall] = "--enable-plugin-videocall,--disable-plugin-videocall,"
> +PACKAGECONFIG[plugin_nosip] = "--enable-plugin-nosip,--disable-plugin-nosip,"
> +PACKAGECONFIG[plugin_videoroom] = "--enable-plugin-videoroom,--disable-plugin-videoroom,"
> +PACKAGECONFIG[plugin_voicemail] = "--enable-plugin-voicemail,--disable-plugin-voicemail,"
> +PACKAGECONFIG[plugin_recordplay] = "--enable-plugin-recordplay,--disable-plugin-recordplay,"
> +PACKAGECONFIG[plugin_textroom] = "--enable-plugin-textroom,--disable-plugin-textroom,"
> +
> +FILES_${PN}_append = " ${libdir}/janus/plugins/* ${libdir}/janus/transports/* ${libdir}/janus/events"
> +FILES_${PN}-demo = "${datadir}/janus/*"
> +
> +PACKAGES_append = " ${PN}-demo"

you could use PACKAGES += "..."

> +
> +INSANE_SKIP_${PN} = "dev-so"

why is this needed.

> +
> +SYSTEMD_SERVICE_${PN} = "janus-gateway.service"
> +
> +do_install_append() {
> +       # Install the systemd service so we can kick start on boot
> +       install -d ${D}${systemd_unitdir}/system
> +       install -m 644 ${WORKDIR}/janus-gateway.service ${D}${systemd_unitdir}/system/
> +}
> --
> 2.7.4
>
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel@lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel