[16/24] linux-qoriq/4.19 : add recipes

Submitted by C.R. Guo on April 1, 2019, 9:12 a.m. | Patch ID: 160006

Details

Message ID 1554109902-31662-16-git-send-email-chunrong.guo@nxp.com
State New
Headers show

Commit Message

C.R. Guo April 1, 2019, 9:12 a.m.
From: Chunrong Guo <chunrong.guo@nxp.com>

*Update to lsdk 1903 tag
include the following changes:
c0c2141 - vfio/fsl-mc: Reset container on last reference release
628aca9 - Revert "net: phy: aquantia: add pause frame support"
99f8355 - Update the year of NXP copyright
66ca144 - powerpc/dts/fsl: add crypto node alias for B4
1d98121 - arm64: dts: ls1043a: add crypto node alias also for qds
bef16ab - soc: fsl: dpio: Increase timeout for QBMan Management Commands
deb34f2 - soc: fsl: qbman: avoid race in clearing QMan interrupt
ab14cd9 - i2c: imx: defer probing on dma channel request
a48d147 - i2c: imx: fix dma_request_chan error handling
a8e3023 - i2c: imx: improve the error handling in i2c_imx_dma_request()
dd6f891 - i2c: imx: notify about real errors on dma i2c_imx_dma_request
9335f72 - crypto: caam - fix building job ring as module
0bc1219 - soc/fsl/bqman: page align iommu mapping sizes
aabe1ef - sdk: dts: remove dma-coherent from sdk dts for QE
68aad5f - net: phy: aquantia: add pause frame support
4f96e7e - staging: fsl-dpaa2/mac: Fix bug in pause frame advertising
1f10c93 - staging: fsl-dpaa2/mac: add pause frames support for managed phys
81c18ad - dpaa2-eth: Update pause frames settings on link up
473f1b9 - dpaa2-eth: fix race condition with bql frame accounting
0ccd3c2 - dpaa2-eth: configure the cache stashing amount on a queue
8992d4e - crypto: caam - move shared symbols in a common location
f8d1f310 - dmaengine: fsl-edma: dma map slave device address
75ea596 - arm64: dts: lx2160a: add flextimer entry

Signed-off-by: Chunrong Guo <chunrong.guo@nxp.com>
---
 recipes-kernel/linux/linux-qoriq_4.19.bb | 72 ++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 recipes-kernel/linux/linux-qoriq_4.19.bb

Patch hide | download patch | download mbox

diff --git a/recipes-kernel/linux/linux-qoriq_4.19.bb b/recipes-kernel/linux/linux-qoriq_4.19.bb
new file mode 100644
index 0000000..c5105d0
--- /dev/null
+++ b/recipes-kernel/linux/linux-qoriq_4.19.bb
@@ -0,0 +1,72 @@ 
+inherit kernel qoriq_build_64bit_kernel siteinfo
+inherit fsl-kernel-localversion
+
+SUMMARY = "Linux Kernel for NXP QorIQ platforms"
+SECTION = "kernel"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=bbea815ee2795b2f4230826c0c6b8814"
+
+SRC_URI = "git://source.codeaurora.org/external/qoriq/qoriq-components/linux;nobranch=1 \
+"
+SRCREV = "c0c2141106240d61e7b9d7c80284711d54f6ae91"
+
+SRC_URI += " file://0001-Makfefile-add-cflags.patch \
+"
+S = "${WORKDIR}/git"
+
+DEPENDS_append = " libgcc"
+# not put Images into /boot of rootfs, install kernel-image if needed
+RDEPENDS_${KERNEL_PACKAGE_NAME}-base = ""
+
+KERNEL_CC_append = " ${TOOLCHAIN_OPTIONS}"
+KERNEL_LD_append = " ${TOOLCHAIN_OPTIONS}"
+KERNEL_EXTRA_ARGS += "LOADADDR=${UBOOT_ENTRYPOINT}"
+
+ZIMAGE_BASE_NAME = "zImage-${PKGE}-${PKGV}-${PKGR}-${MACHINE}-${DATETIME}"
+ZIMAGE_BASE_NAME[vardepsexclude] = "DATETIME"
+
+SCMVERSION ?= "y"
+LOCALVERSION = ""
+DELTA_KERNEL_DEFCONFIG ?= ""
+DELTA_KERNEL_DEFCONFIG_prepend_qoriq-arm64 = "lsdk.config "
+DELTA_KERNEL_DEFCONFIG_prepend_fsl-lsch2-32b = "multi_v7_lpae.config multi_v8.config lsdk.config "
+DELTA_KERNEL_DEFCONFIG_prepend_ls102xa = "multi_v7_lpae.config lsdk.config "
+
+do_merge_delta_config[depends] += "virtual/${TARGET_PREFIX}gcc:do_populate_sysroot"
+do_merge_delta_config[dirs] = "${B}"
+
+do_merge_delta_config() {
+    # create config with make config
+    oe_runmake  -C ${S} O=${B} ${KERNEL_DEFCONFIG}
+    
+    # check if bigendian is enabled
+    if [ "${SITEINFO_ENDIANNESS}" = "be" ]; then
+        echo "CONFIG_CPU_BIG_ENDIAN=y" >> .config
+        echo "CONFIG_MTD_CFI_BE_BYTE_SWAP=y" >> .config
+    fi
+
+    # add config fragments
+    for deltacfg in ${DELTA_KERNEL_DEFCONFIG}; do
+        if [ -f ${S}/arch/${ARCH}/configs/${deltacfg} ]; then
+            oe_runmake  -C ${S} O=${B} ${deltacfg}
+        elif [ -f "${WORKDIR}/${deltacfg}" ]; then
+            ${S}/scripts/kconfig/merge_config.sh -m .config ${WORKDIR}/${deltacfg}
+        elif [ -f "${deltacfg}" ]; then
+            ${S}/scripts/kconfig/merge_config.sh -m .config ${deltacfg}
+        fi
+    done
+    cp .config ${WORKDIR}/defconfig
+}
+addtask merge_delta_config before do_preconfigure after do_patch
+
+# The link of dts folder is needed for 32b compile of aarch64 targets(e.g. ls1043ardb-32b)
+do_compile_prepend_fsl-lsch2-32b() {
+    ln -sfT ${STAGING_KERNEL_DIR}/arch/arm64/boot/dts/freescale ${STAGING_KERNEL_DIR}/arch/arm/boot/dts/freescale
+}
+
+do_install_prepend_fsl-lsch2-32b() {
+    rm -f ${STAGING_KERNEL_DIR}/arch/arm/boot/dts/freescale
+}
+
+FILES_${KERNEL_PACKAGE_NAME}-image += "/boot/zImage*"
+COMPATIBLE_MACHINE = "(qoriq)"