[meta-oe,1/2] libseccomp: move lib from meta-security to meta-oe

Submitted by Armin Kuster on June 1, 2018, 3:10 p.m. | Patch ID: 151322

Details

Message ID 1527865814-9027-1-git-send-email-akuster808@gmail.com
State Changes Requested
Headers show

Commit Message

Armin Kuster June 1, 2018, 3:10 p.m.
Signed-off-by: Armin Kuster <akuster808@gmail.com>
---
 .../recipes-security/libseccomp/files/run-ptest    |  4 +++
 .../libseccomp/libseccomp_2.3.3.bb                 | 42 ++++++++++++++++++++++
 2 files changed, 46 insertions(+)
 create mode 100644 meta-oe/recipes-security/libseccomp/files/run-ptest
 create mode 100644 meta-oe/recipes-security/libseccomp/libseccomp_2.3.3.bb

Patch hide | download patch | download mbox

diff --git a/meta-oe/recipes-security/libseccomp/files/run-ptest b/meta-oe/recipes-security/libseccomp/files/run-ptest
new file mode 100644
index 0000000..54b4a63
--- /dev/null
+++ b/meta-oe/recipes-security/libseccomp/files/run-ptest
@@ -0,0 +1,4 @@ 
+#!/bin/sh
+
+cd tests
+./regression -a
diff --git a/meta-oe/recipes-security/libseccomp/libseccomp_2.3.3.bb b/meta-oe/recipes-security/libseccomp/libseccomp_2.3.3.bb
new file mode 100644
index 0000000..8d58163
--- /dev/null
+++ b/meta-oe/recipes-security/libseccomp/libseccomp_2.3.3.bb
@@ -0,0 +1,42 @@ 
+SUMMARY = "interface to seccomp filtering mechanism"
+DESCRIPTION = "The libseccomp library provides and easy to use, platform independent,interface to the Linux Kernel's syscall filtering mechanism: seccomp."
+SECTION = "security"
+LICENSE = "LGPL-2.1"
+LIC_FILES_CHKSUM = "file://LICENSE;beginline=0;endline=1;md5=8eac08d22113880357ceb8e7c37f989f"
+
+SRCREV = "74b190e1aa05f07da0c61fb9a30dbc9c18ce2c9d"
+
+SRC_URI = "git://github.com/seccomp/libseccomp.git;branch=release-2.3 \
+           file://run-ptest \
+"
+
+S = "${WORKDIR}/git"
+
+inherit autotools-brokensep pkgconfig ptest
+
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[python] = "--enable-python, --disable-python, python"
+
+do_compile_ptest() {
+    oe_runmake -C tests check-build
+}
+
+do_install_ptest() {
+    install -d ${D}${PTEST_PATH}/tests
+    install -d ${D}${PTEST_PATH}/tools
+    for file in $(find tests/* -executable -type f); do
+        install -m 744 ${S}/${file} ${D}/${PTEST_PATH}/tests
+    done
+    for file in $(find tests/*.tests -type f); do
+        install -m 744 ${S}/${file} ${D}/${PTEST_PATH}/tests
+    done
+    for file in $(find tools/* -executable -type f); do
+        install -m 744 ${S}/${file} ${D}/${PTEST_PATH}/tools
+    done
+}
+
+FILES_${PN} = "${bindir} ${libdir}/${PN}.so*"
+FILES_${PN}-dbg += "${libdir}/${PN}/tests/.debug/* ${libdir}/${PN}/tools/.debug"
+
+RDEPENDS_${PN} = "bash"
+RDEPENDS_${PN}-ptest = "bash"

Comments

Khem Raj June 1, 2018, 4:52 p.m.
On 6/1/18 8:10 AM, Armin Kuster wrote:
> Signed-off-by: Armin Kuster <akuster808@gmail.com>
> ---
>  .../recipes-security/libseccomp/files/run-ptest    |  4 +++
>  .../libseccomp/libseccomp_2.3.3.bb                 | 42 ++++++++++++++++++++++
>  2 files changed, 46 insertions(+)
>  create mode 100644 meta-oe/recipes-security/libseccomp/files/run-ptest
>  create mode 100644 meta-oe/recipes-security/libseccomp/libseccomp_2.3.3.bb
> 
> diff --git a/meta-oe/recipes-security/libseccomp/files/run-ptest b/meta-oe/recipes-security/libseccomp/files/run-ptest
> new file mode 100644
> index 0000000..54b4a63
> --- /dev/null
> +++ b/meta-oe/recipes-security/libseccomp/files/run-ptest
> @@ -0,0 +1,4 @@
> +#!/bin/sh
> +
> +cd tests
> +./regression -a

should this recover to old pwd after run is over ?

> diff --git a/meta-oe/recipes-security/libseccomp/libseccomp_2.3.3.bb b/meta-oe/recipes-security/libseccomp/libseccomp_2.3.3.bb
> new file mode 100644
> index 0000000..8d58163
> --- /dev/null
> +++ b/meta-oe/recipes-security/libseccomp/libseccomp_2.3.3.bb
> @@ -0,0 +1,42 @@
> +SUMMARY = "interface to seccomp filtering mechanism"
> +DESCRIPTION = "The libseccomp library provides and easy to use, platform independent,interface to the Linux Kernel's syscall filtering mechanism: seccomp."
> +SECTION = "security"
> +LICENSE = "LGPL-2.1"
> +LIC_FILES_CHKSUM = "file://LICENSE;beginline=0;endline=1;md5=8eac08d22113880357ceb8e7c37f989f"
> +
> +SRCREV = "74b190e1aa05f07da0c61fb9a30dbc9c18ce2c9d"
> +
> +SRC_URI = "git://github.com/seccomp/libseccomp.git;branch=release-2.3 \
> +           file://run-ptest \
> +"
> +
> +S = "${WORKDIR}/git"
> +
> +inherit autotools-brokensep pkgconfig ptest
> +
> +PACKAGECONFIG ??= ""
> +PACKAGECONFIG[python] = "--enable-python, --disable-python, python"
> +
> +do_compile_ptest() {
> +    oe_runmake -C tests check-build
> +}
> +
> +do_install_ptest() {
> +    install -d ${D}${PTEST_PATH}/tests
> +    install -d ${D}${PTEST_PATH}/tools
> +    for file in $(find tests/* -executable -type f); do
> +        install -m 744 ${S}/${file} ${D}/${PTEST_PATH}/tests
> +    done
> +    for file in $(find tests/*.tests -type f); do
> +        install -m 744 ${S}/${file} ${D}/${PTEST_PATH}/tests
> +    done
> +    for file in $(find tools/* -executable -type f); do
> +        install -m 744 ${S}/${file} ${D}/${PTEST_PATH}/tools
> +    done
> +}
> +
> +FILES_${PN} = "${bindir} ${libdir}/${PN}.so*"

I wonder if library should be packaged separately then any binary
utilities that accompanies it.

> +FILES_${PN}-dbg += "${libdir}/${PN}/tests/.debug/* ${libdir}/${PN}/tools/.debug"
> +
> +RDEPENDS_${PN} = "bash"
> +RDEPENDS_${PN}-ptest = "bash"
> 

Is this dep needed in some other scripts that are run ? the ptest runner
script itself seems to not need bash