Patchwork [meta-oe,10/19] xfce4-panel: Add initial recipe with version 4.8.5

login
register
mail settings
Submitter Andreas Müller
Date Aug. 1, 2011, 9:02 p.m.
Message ID <1312232577-7948-11-git-send-email-schnitzeltony@gmx.de>
Download mbox | patch
Permalink /patch/8989/
State Accepted
Headers show

Comments

Andreas Müller - Aug. 1, 2011, 9:02 p.m.
Signed-off-by: Andreas Mueller <schnitzeltony@gmx.de>
---
 .../recipes-xfce/xfce4-panel/xfce4-panel_4.8.5.bb  |   34 ++++++++++++++++++++
 1 files changed, 34 insertions(+), 0 deletions(-)
 create mode 100644 meta-xfce/recipes-xfce/xfce4-panel/xfce4-panel_4.8.5.bb

Patch

diff --git a/meta-xfce/recipes-xfce/xfce4-panel/xfce4-panel_4.8.5.bb b/meta-xfce/recipes-xfce/xfce4-panel/xfce4-panel_4.8.5.bb
new file mode 100644
index 0000000..d99f332
--- /dev/null
+++ b/meta-xfce/recipes-xfce/xfce4-panel/xfce4-panel_4.8.5.bb
@@ -0,0 +1,34 @@ 
+DESCRIPTION = "Xfce4 Panel"
+SECTION = "x11"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=26a8bd75d8f8498bdbbe64a27791d4ee"
+DEPENDS = "libxfce4util garcon libxfce4ui xfconf exo gtk+ dbus cairo virtual/libx11 libxml2 libwnck"
+
+PR = "r0"
+
+inherit xfce
+
+python populate_packages_prepend() {
+	plugin_dir = bb.data.expand('${libdir}/xfce4/panel/plugins/', d)
+	plugin_name = bb.data.expand('${PN}-plugin-%s', d)
+	do_split_packages(d, plugin_dir, '^lib(.*).so$', plugin_name,
+	                  '${PN} plugin for %s', extra_depends='', prepend=True,
+	                  aux_files_pattern=['${datadir}/xfce4/panel/plugins/%s.desktop',
+	                                     '${sysconfdir}/xdg/xfce/panel/%s-*',
+	                                     '${datadir}/icons/hicolor/48x48/apps/*-%s.png',
+	                                     '${bindir}/*%s*'])
+}
+
+PACKAGES_DYNAMIC = "${PN}-plugin-*"
+
+FILES_${PN} += "${libdir}/xfce4/panel/migrate \
+                ${libdir}/xfce4/panel/wrapper"
+
+FILES_${PN}-dbg += "${libdir}/xfce4/panel/plugins/.debug \
+		   "
+
+FILES_${PN}-dev += "${libdir}/xfce4/panel/plugins/*.*a \
+                   "
+
+SRC_URI[md5sum] = "3c00e92821709baa2a71b166a32d46a2"
+SRC_URI[sha256sum] = "df8379a18d337481b847cf232eec907a927287917788e7b730deef4a535deada"