Patchwork [meta-oe] fim: add newrecipe for version 0.4-rc1

login
register
mail settings
Submitter Matthieu CRAPET
Date Feb. 28, 2014, 4:51 p.m.
Message ID <1393606261-26991-1-git-send-email-Matthieu.Crapet@ingenico.com>
Download mbox | patch
Permalink /patch/67741/
State Accepted, archived
Headers show

Comments

Matthieu CRAPET - Feb. 28, 2014, 4:51 p.m.
FIM (Fbi IMproved) is a framebuffer (customizable and scriptable) image viewer.
It is based on Fbi image viewer.

Signed-off-by: Matthieu Crapet <Matthieu.Crapet@ingenico.com>
---
 meta-oe/recipes-graphics/fim/fim_0.4-rc1.bb | 48 +++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 meta-oe/recipes-graphics/fim/fim_0.4-rc1.bb

Patch

diff --git a/meta-oe/recipes-graphics/fim/fim_0.4-rc1.bb b/meta-oe/recipes-graphics/fim/fim_0.4-rc1.bb
new file mode 100644
index 0000000..01aa87c
--- /dev/null
+++ b/meta-oe/recipes-graphics/fim/fim_0.4-rc1.bb
@@ -0,0 +1,48 @@ 
+SUMMARY = "Framebuffer (scriptable) image viewer"
+DESCRIPTION = "FIM (Fbi IMproved) aims to be a highly customizable and scriptable \
+               image viewer targeted at users who are comfortable with software \
+               like the Vim text editor or the Mutt mail user agent."
+SECTION = "utils"
+HOMEPAGE = "http://www.autistici.org/dezperado/fim/"
+
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=fa01bff138cc98a62b8840a157951c88"
+
+# flex with provide /usr/include/FlexLexer.h
+DEPENDS = "flex-native bison-native flex"
+
+SRC_URI = "http://download.savannah.nongnu.org/releases/fbi-improved/${BPN}-${PV}.tar.gz"
+SRC_URI[md5sum] = "d7362dde5541c2b6439c35c6e2bd5046"
+SRC_URI[sha256sum] = "3f6bf2de2952b9adcbeb3db12c2a979e999a81dd1e314a03bc58e24f1ea9f686"
+
+PARALLEL_MAKE = ""
+
+inherit autotools
+
+# Don't use provided regex.c
+EXTRA_OECONF = "fim_cv_regex=no fim_cv_regex_broken=no \
+    --enable-framebuffer \
+    --disable-djvu \
+    --disable-ps \
+    --disable-xcftopnm \
+    --disable-convert \
+    --disable-inkscape \
+    --disable-xfig \
+    --disable-dia \
+    --disable-aa \
+    --disable-sdl \
+    --enable-read-dirs \
+    --enable-recursive-dirs \
+    --enable-custom-status-bar \
+"
+
+# Note: imlib2 is located in meta-efl layer.
+PACKAGECONFIG ??= "jpeg rl"
+PACKAGECONFIG[png] = "--enable-png,--disable-png,libpng"
+PACKAGECONFIG[jpeg] = "--enable-jpeg,--disable-jpeg,jpeg"
+PACKAGECONFIG[tiff] = "--enable-tiff,--disable-tiff,tiff"
+PACKAGECONFIG[gif] = "--enable-gif,--disable-gif,giflib"
+PACKAGECONFIG[pdf] = "--enable-poppler,--disable-poppler,poppler"
+PACKAGECONFIG[magick] = "--enable-graphicsmagick,--disable-graphicsmagick,imagemagick"
+PACKAGECONFIG[imlib2] = "--enable-imlib2,--disable-imlib2,imlib2"
+PACKAGECONFIG[rl] = "--enable-readline,--disable-readline,readline"