Patchwork [meta-fsl-demos,v2,1/7] fsl-gpu-sdk: create version 1.1 recipe

login
register
mail settings
Submitter Rogerio Nunes
Date Feb. 27, 2014, 7:53 a.m.
Message ID <1393487638-5096-1-git-send-email-ronunes@gmail.com>
Download mbox | patch
Permalink /patch/67557/
State Accepted
Delegated to: Otavio Salvador
Headers show

Comments

Rogerio Nunes - Feb. 27, 2014, 7:53 a.m.
From: Evan Kotara <evan.kotara@freescale.com>

This patch results from a squash between two patches from the
meta-fsl-bsp-release layer:
    http://git.freescale.com/git/cgit.cgi/imx/me
    7f3add015f2f... fsl-gpu-sdk: create version 1.1 recipe
    27452615b9b1... fsl-gpu-sdk: Prefer X11 if wayland is also in distro features

It creates the fsl-gpu-sdk recipe, which is equivalent to the vivante-gpu-sdk
recipe currenly in use.

The new recipe name reflects the name of the most recent gpu sdk package name
released by freescale, so the intention is to remove the old recipe in a
separete commit.

If both X11 and Wayland are in DISTRO_FEATURES, prefer X11.

Signed-off-by: Evan Kotara <evan.kotara@freescale.com>
Signed-off-by: Rogerio Nunes <rogerio.nunes@freescale.com>
---
 recipes-graphics/fsl-gpu-sdk/fsl-gpu-sdk_1.1.bb | 40 +++++++++++++++++++++++++
 1 file changed, 40 insertions(+)
 create mode 100644 recipes-graphics/fsl-gpu-sdk/fsl-gpu-sdk_1.1.bb

Patch

diff --git a/recipes-graphics/fsl-gpu-sdk/fsl-gpu-sdk_1.1.bb b/recipes-graphics/fsl-gpu-sdk/fsl-gpu-sdk_1.1.bb
new file mode 100644
index 0000000..812e23d
--- /dev/null
+++ b/recipes-graphics/fsl-gpu-sdk/fsl-gpu-sdk_1.1.bb
@@ -0,0 +1,40 @@ 
+SUMMARY = "Freescale GPU SDK Samples"
+DESCRIPTION = "Set of sample applications for Freescale GPU"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://COPYING;md5=44e96dac83a60d6c21a6055f7b31cf0c"
+DEPENDS = "virtual/libgles1 virtual/libgles2 ${WL_DEPENDS}"
+WL_DEPENDS = "${@base_contains('DISTRO_FEATURES', 'wayland', 'wayland', '', d)}"
+
+inherit fsl-eula-unpack
+
+SRC_URI = "${FSL_MIRROR}/${PN}-${PV}.bin;fsl-eula=true"
+SRC_URI[md5sum] = "7cf0e66cfc6202a51bdd42573e601e6a"
+SRC_URI[sha256sum] = "89e3753b343b67e3a0d82fe3e96f0b388e73a650c2a00c767cf67efce7d0c217"
+
+S = "${WORKDIR}/${PN}-${PV}"
+
+SUPPORTED_APIS = "GLES1.1 GLES2.0 ${@base_contains('DISTRO_FEATURES', 'x11', '', 'OpenVG', d)}"
+MAKEFILE_NO_X11 = "${@base_contains('DISTRO_FEATURES', 'wayland', 'Makefile.wl', 'Makefile.fbdev', d)}"
+MAKEFILE = "${@base_contains('DISTRO_FEATURES', 'x11', 'Makefile.x11', '${MAKEFILE_NO_X11}', d)}"
+
+EXTRA_OEMAKE += "YOCTO_BUILD=1"
+
+do_compile () {
+    export ROOTFS=${STAGING_DIR_HOST}
+    for API in ${SUPPORTED_APIS}; do
+        cd "${S}/Samples/${API}"
+        oe_runmake -f "${MAKEFILE}"
+    done
+}
+
+do_install () {
+    install -d "${D}/opt/${PN}"
+    for API in ${SUPPORTED_APIS}; do
+        cd "${S}/Samples/${API}"
+        oe_runmake -f "${MAKEFILE}" install
+        cp -r bin/* "${D}/opt/${PN}"
+    done
+}
+
+FILES_${PN} += "/opt/${PN}"
+FILES_${PN}-dbg += "/opt/${PN}/*/.debug"