Patchwork [meta-oe,v2] tipcutils: add recipe

login
register
mail settings
Submitter Ting Liu
Date Sept. 24, 2013, 7:17 a.m.
Message ID <1380007056-16010-1-git-send-email-b28495@freescale.com>
Download mbox | patch
Permalink /patch/58635/
State Accepted, archived
Commit e5da5ebff6dd6964bbeb37a39bbf8afa30ce92da
Headers show

Comments

Ting Liu - Sept. 24, 2013, 7:17 a.m.
From: Ting Liu <b28495@freescale.com>

The Transparent Inter-Process Communication protocol allows applications
in a clustered computer environment to communicate quickly and reliably
with other applications, regardless of their location within the
cluster.

demo binaries are packaged to tipcutils-demos.

Signed-off-by: Ting Liu <b28495@freescale.com>
---
v2: add subdirectory meta-oe/

 .../recipes-extended/tipcutils/tipcutils_2.0.6.bb  |   40 ++++++++++++++++++++
 1 files changed, 40 insertions(+), 0 deletions(-)
 create mode 100644 meta-oe/recipes-extended/tipcutils/tipcutils_2.0.6.bb

Patch

diff --git a/meta-oe/recipes-extended/tipcutils/tipcutils_2.0.6.bb b/meta-oe/recipes-extended/tipcutils/tipcutils_2.0.6.bb
new file mode 100644
index 0000000..f91ef0e
--- /dev/null
+++ b/meta-oe/recipes-extended/tipcutils/tipcutils_2.0.6.bb
@@ -0,0 +1,40 @@ 
+DESCRIPTION = "Transparent Inter-Process Communication protocol"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://tipc-config/tipc-config.c;endline=32;md5=527a3d5745e1581b15a4fddfb5dfda68"
+
+SRC_URI = "git://tipc.git.sourceforge.net/gitroot/tipc/tipcutils"
+SRCREV = "292a03e17f889013fca2c7bd0aaeebd600c88f40"
+
+DEPENDS="virtual/kernel"
+
+inherit autotools
+
+S = "${WORKDIR}/git"
+
+do_configure_prepend() {
+    ( cd ${S}; ${S}/bootstrap )
+}
+
+do_install_append() {
+    demos="benchmark hello_world topology_subscr_demo connection_demo \
+           multicast_demo stream_demo"
+    for i in $demos;do
+        install -d ${D}/opt/tipcutils/demos/$i
+        install ${S}/demos/$i/client_tipc ${D}/opt/tipcutils/demos/$i/
+        install ${S}/demos/$i/server_tipc ${D}/opt/tipcutils/demos/$i/
+    done
+    install -d ${D}/opt/tipcutils/demos/inventory_sim
+    install ${S}/demos/inventory_sim/inventory_sim ${D}/opt/tipcutils/demos/inventory_sim/
+
+    install -d ${D}/opt/tipcutils/ptts
+    install ${S}/ptts/tipcTS ${D}/opt/tipcutils/ptts/
+    install ${S}/ptts/tipcTC ${D}/opt/tipcutils/ptts/
+
+    install -d ${D}${sysconfdir}
+    cp -a ${S}/scripts/etc/* ${D}${sysconfdir}/
+}
+
+PACKAGES += "${PN}-demos"
+FILES_${PN}-dbg += "/opt/tipcutils/demos/*/.debug /opt/tipcutils/ptts/.debug"
+FILES_${PN}-demos = "/opt/tipcutils/*"
+