Patchwork [3/3] Initial commit for wayland/weston 1.0.3

login
register
mail settings
Submitter Alexandru DAMIAN
Date Jan. 7, 2013, 4:06 p.m.
Message ID <6b9684a5239103564b499be51bfe655bf89abea4.1357574641.git.alexandru.damian@intel.com>
Download mbox | patch
Permalink /patch/42229/
State New
Headers show

Comments

Alexandru DAMIAN - Jan. 7, 2013, 4:06 p.m.
From: Alexandru DAMIAN <alexandru.damian@intel.com>

This patch adds the Weston reference compositing
manager from Wayland.

We add version 1.0.3 which is the latest stable release
in Dec 2012. See the upstream at:

http://wayland.freedesktop.org/releases.html

To enable building, set in local.conf

 #Build mesa-dri compatible packages
 OVERRIDES += ":weston"
 #Enable the wayland distro feature
 DISTRO_FEATURES_append_weston = " wayland "

Signed-off-by: Alexandru DAMIAN <alexandru.damian@intel.com>
---
 meta/recipes-graphics/wayland/weston.inc      |   23 +++++++++++++++++++++++
 meta/recipes-graphics/wayland/weston_1.0.3.bb |    9 +++++++++
 2 files changed, 32 insertions(+)
 create mode 100644 meta/recipes-graphics/wayland/weston.inc
 create mode 100644 meta/recipes-graphics/wayland/weston_1.0.3.bb
Ross Burton - Jan. 8, 2013, 9:58 a.m.
On 7 January 2013 16:06, Alex DAMIAN <alexandru.damian@intel.com> wrote:
> From: Alexandru DAMIAN <alexandru.damian@intel.com>
>
> This patch adds the Weston reference compositing
> manager from Wayland.
>
> We add version 1.0.3 which is the latest stable release
> in Dec 2012. See the upstream at:
>
> http://wayland.freedesktop.org/releases.html

Remove this, it's obvious from the commit which version you're using.

> To enable building, set in local.conf
>
>  #Build mesa-dri compatible packages
>  OVERRIDES += ":weston"

As in 2/3, don't do this.

>  #Enable the wayland distro feature
>  DISTRO_FEATURES_append_weston = " wayland "

Surely you want the wayland feature globally, so that mesa builds with
Wayland support?  'To enable wayland, add "wayland" to
DISTRO_FEATURES.' is all you need.

Ross

Patch

diff --git a/meta/recipes-graphics/wayland/weston.inc b/meta/recipes-graphics/wayland/weston.inc
new file mode 100644
index 0000000..2293589
--- /dev/null
+++ b/meta/recipes-graphics/wayland/weston.inc
@@ -0,0 +1,23 @@ 
+inherit autotools pkgconfig
+
+SUMMARY = "Weston, a Wayland compositor"
+DESCRIPTION = "Weston is the reference implementation of a Wayland compositor"
+HOMEPAGE = "http://wayland.freedesktop.org"
+SECTION = "wayland/base"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING;md5=275efac2559a224527bd4fd593d38466"
+
+DEPENDS = "wayland mesa-dri libxkbcommon gdk-pixbuf pixman cairo glib-2.0 mtdev jpeg"
+DEPENDS += "virtual/egl"
+
+EXTRA_OECONF  = "--enable-wayland-compositor --disable-android-compositor"
+EXTRA_OECONF += "--enable-setuid-install --enable-simple-clients"
+EXTRA_OECONF += "--enable-clients --disable-xwayland"
+
+PACKAGECONFIG ??= "${@base_contains('DISTRO_FEATURES', 'wayland', 'kms', '', d)} \
+                   ${@base_contains('DISTRO_FEATURES', 'x11', 'x11', '', d)} \
+                   ${@base_contains('DISTRO_FEATURES', 'opengles2', 'gles', '', d)} \
+                  "
+PACKAGECONFIG[kms] = "--enable-drm-compositor,--disable-drm-compositor,drm udev mesa-dri libpam"
+PACKAGECONFIG[x11] = "--enable-x11-compositor,--disable-x11-compositor,virtual/libx11 libxcb libxcb libxcursor cairo"
+PACKAGECONFIG[gles] = "--with-cairo-glesv2,,virtual/libgles2"
diff --git a/meta/recipes-graphics/wayland/weston_1.0.3.bb b/meta/recipes-graphics/wayland/weston_1.0.3.bb
new file mode 100644
index 0000000..625965b
--- /dev/null
+++ b/meta/recipes-graphics/wayland/weston_1.0.3.bb
@@ -0,0 +1,9 @@ 
+require weston.inc
+
+SRC_URI = "http://wayland.freedesktop.org/releases/weston-1.0.3.tar.xz \
+	  "
+SRC_URI[md5sum] = "f82ac2e013e6b6a6303ac4ba7b64c7f2"
+SRC_URI[sha256sum] = "3136a7d2f654ea3e946d4217f7e25321248ad2921f1f4e2504dda58968e04853"
+
+PR = "r0"
+