diff mbox series

[meta-python,5/5] python3-httpx: add recipe for v0.26.0

Message ID 20240205125829.152301-6-dev@g0hl1n.net
State Accepted
Headers show
Series Add python3-httpx support | expand

Commit Message

Richard Leitner Feb. 5, 2024, 12:58 p.m. UTC 
The next generation HTTP client. This recipe uses pypi as source:

    https://pypi.org/project/httpx

Signed-off-by: Richard Leitner <dev@g0hl1n.net>
---
 .../python/python3-httpx_0.26.0.bb            | 44 +++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 meta-python/recipes-devtools/python/python3-httpx_0.26.0.bb
diff mbox series

Patch

diff --git a/meta-python/recipes-devtools/python/python3-httpx_0.26.0.bb b/meta-python/recipes-devtools/python/python3-httpx_0.26.0.bb
new file mode 100644
index 000000000..9abd13e2b
--- /dev/null
+++ b/meta-python/recipes-devtools/python/python3-httpx_0.26.0.bb
@@ -0,0 +1,44 @@ 
+SUMMARY = "A next generation HTTP client for Python."
+SECTION = "devel/python"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=c624803bdf6fc1c4ce39f5ae11d7bd05"
+
+inherit pypi python_hatchling
+
+SRC_URI[sha256sum] = "451b55c30d5185ea6b23c2c793abf9bb237d2a7dfb901ced6ff69ad37ec1dfaf"
+
+DEPENDS += "\
+    python3-hatch-fancy-pypi-readme-native \
+"
+
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[brotli] = ",,,python3-brotli"
+PACKAGECONFIG[http2] = ",,,python3-h2"
+PACKAGECONFIG[socks] = ",,,python3-socksio"
+
+RDEPENDS:${PN} += "\
+    python3-anyio \
+    python3-certifi \
+    python3-httpcore \
+    python3-idna \
+    python3-sniffio \
+"
+
+PACKAGES += "\
+    ${PN}-cli \
+"
+
+RDEPENDS:${PN}-cli += "\
+    ${PN} \
+    python3-click \
+    python3-pygments \
+    python3-rich \
+"
+
+FILES:${PN} = "\
+    /usr/lib/python${PYTHON_BASEVERSION} \
+"
+
+FILES:${PN}-cli = "\
+    /usr/bin/httpx \
+"