Patchwork [meta-oe,3/5] libpostproc: Add git version

login
register
mail settings
Submitter Otavio Salvador
Date Oct. 6, 2012, 8:18 p.m.
Message ID <1349554710-6693-3-git-send-email-otavio@ossystems.com.br>
Download mbox | patch
Permalink /patch/37865/
State Accepted
Commit 2935a21d38de8b7130cbd80edfb097f2dac4a1d1
Headers show

Comments

Otavio Salvador - Oct. 6, 2012, 8:18 p.m.
This has been split from libav code during development of 0.9 series.

Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
---
 .../libpostproc/libpostproc_git.bb                 |   49 ++++++++++++++++++++
 1 files changed, 49 insertions(+), 0 deletions(-)
 create mode 100644 meta-oe/recipes-multimedia/libpostproc/libpostproc_git.bb

Patch

diff --git a/meta-oe/recipes-multimedia/libpostproc/libpostproc_git.bb b/meta-oe/recipes-multimedia/libpostproc/libpostproc_git.bb
new file mode 100644
index 0000000..3620ff0
--- /dev/null
+++ b/meta-oe/recipes-multimedia/libpostproc/libpostproc_git.bb
@@ -0,0 +1,49 @@ 
+DESCRIPTION = "FFmpeg derived postprocessing library"
+HOMEPAGE = "http://git.videolan.org/?p=libpostproc.git;a=summary"
+SECTION = "libs"
+DEPENDS = "libav"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+
+PV = "0.0.0+git${SRCPV}"
+
+DEFAULT_PREFERENCE = "-1"
+
+SRCREV = "3b7053f46dbfe4662063345245cb00b6acbbe969"
+SRC_URI = "git://git.videolan.org/libpostproc.git"
+
+S = "${WORKDIR}/git"
+
+inherit autotools lib_package pkgconfig
+
+FULL_OPTIMIZATION_armv7a = "-fexpensive-optimizations -fomit-frame-pointer -O4 -ffast-math"
+BUILD_OPTIMIZATION = "${FULL_OPTIMIZATION}"
+
+EXTRA_FFCONF_armv7a = "--cpu=cortex-a8"
+EXTRA_FFCONF ?= ""
+
+EXTRA_OECONF = " \
+        --enable-shared \
+        --enable-pthreads \
+        --enable-gpl \
+        --enable-postproc \
+        \
+        --cross-prefix=${TARGET_PREFIX} \
+        --prefix=${prefix} \
+        \
+        --arch=${TARGET_ARCH} \
+        --target-os="linux" \
+        --enable-cross-compile \
+        --extra-cflags="${TARGET_CFLAGS} ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}" \
+        --extra-ldflags="${TARGET_LDFLAGS}" \
+        --sysroot="${STAGING_DIR_TARGET}" \
+        ${EXTRA_FFCONF} \
+"
+
+#| yasm not found, use --disable-yasm for a crippled build
+EXTRA_OECONF_append_x86-64 = " --disable-yasm"
+EXTRA_OECONF_append_x86 = " --disable-yasm"
+
+do_configure() {
+    ./configure ${EXTRA_OECONF}
+}