Patchwork [meta-webserver,v2,4/4] xdebug: add new recipe

login
register
mail settings
Submitter Paul Eggleton
Date Oct. 3, 2012, 5:08 p.m.
Message ID <6190260bea64aa19834ce468a67d5251ded08259.1349283829.git.paul.eggleton@linux.intel.com>
Download mbox | patch
Permalink /patch/37721/
State Accepted
Commit 6190260bea64aa19834ce468a67d5251ded08259
Headers show

Comments

Paul Eggleton - Oct. 3, 2012, 5:08 p.m.
Add new recipe for the Xdebug PHP debugger/profiler.

Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com>
---
 meta-webserver/recipes-php/xdebug/xdebug_2.2.1.bb |   34 +++++++++++++++++++++
 1 file changed, 34 insertions(+)
 create mode 100644 meta-webserver/recipes-php/xdebug/xdebug_2.2.1.bb

Patch

diff --git a/meta-webserver/recipes-php/xdebug/xdebug_2.2.1.bb b/meta-webserver/recipes-php/xdebug/xdebug_2.2.1.bb
new file mode 100644
index 0000000..48e1f8e
--- /dev/null
+++ b/meta-webserver/recipes-php/xdebug/xdebug_2.2.1.bb
@@ -0,0 +1,34 @@ 
+SUMMARY = "Debugging and profiling extension for PHP"
+LICENSE = "Xdebug"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=34df3a274aa12b795417c65634c07f16"
+
+DEPENDS = "modphp"
+
+PR = "r0"
+
+SRC_URI = "http://xdebug.org/files/xdebug-${PV}.tgz"
+
+SRC_URI[md5sum] = "5e5c467e920240c20f165687d7ac3709"
+SRC_URI[sha256sum] = "11d340eb7f87909a596bac054cc927df757dc2fc7c90b50a832c30e9bf84c9ad"
+
+inherit autotools
+
+EXTRA_OECONF += "--enable-xdebug -with-php-config=${STAGING_BINDIR_CROSS}/php-config"
+
+do_configure() {
+	${STAGING_BINDIR_CROSS}/phpize
+
+	# Running autoreconf as autotools_do_configure would do here
+	# breaks the libtool configuration resulting in a failure later
+	# in do_compile. It's possible this may be fixable, however the
+	# easiest course of action for the moment is to avoid doing that.
+	oe_runconf
+}
+
+do_install() {
+	oe_runmake install INSTALL_ROOT=${D}
+}
+
+FILES_${PN} += "${libdir}/php5/extensions/*/*.so"
+FILES_${PN}-dbg += "${libdir}/php5/extensions/*/.debug"
+