Patchwork [meta-oe,9/9] xfsprogs: add

login
register
mail settings
Submitter Zhenhua Luo
Date Dec. 16, 2011, 2:39 a.m.
Message ID <1324003173-13994-9-git-send-email-b19537@freescale.com>
Download mbox | patch
Permalink /patch/17075/
State Superseded
Headers show

Comments

Zhenhua Luo - Dec. 16, 2011, 2:39 a.m.
From: Zhenhua Luo <b19537@freescale.com>

    xfsprogs provides XFS filesystem utilities.

Signed-off-by: Zhenhua Luo <b19537@freescale.com>
---
 meta-oe/recipes-support/xfsprogs/xfsprogs_3.1.7.bb |   43 ++++++++++++++++++++
 1 files changed, 43 insertions(+), 0 deletions(-)
 create mode 100644 meta-oe/recipes-support/xfsprogs/xfsprogs_3.1.7.bb
Koen Kooi - Dec. 16, 2011, 7:54 a.m.
-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

Op 16-12-11 03:39, b19537@freescale.com schreef:
> From: Zhenhua Luo <b19537@freescale.com>
> 
> xfsprogs provides XFS filesystem utilities.
> 
> Signed-off-by: Zhenhua Luo <b19537@freescale.com> --- 
> meta-oe/recipes-support/xfsprogs/xfsprogs_3.1.7.bb |   43
> ++++++++++++++++++++ 1 files changed, 43 insertions(+), 0 deletions(-) 
> create mode 100644 meta-oe/recipes-support/xfsprogs/xfsprogs_3.1.7.bb
> 
> diff --git a/meta-oe/recipes-support/xfsprogs/xfsprogs_3.1.7.bb
> b/meta-oe/recipes-support/xfsprogs/xfsprogs_3.1.7.bb new file mode
> 100644 index 0000000..07644ac --- /dev/null +++
> b/meta-oe/recipes-support/xfsprogs/xfsprogs_3.1.7.bb @@ -0,0 +1,43 @@ 
> +DESCRIPTION = "XFS Filesystem Utilities" +HOMEPAGE =
> "http://oss.sgi.com/projects/xfs" +LICENSE = "GPL"

not a valid license

> +SECTION = "base" +DEPENDS = "util-linux" + +LIC_FILES_CHKSUM =
> "file://Makefile;endline=3;md5=def2844770bb44eba37bc9ca8610fad4"

move next to LICENSE

> + +SRC_URI = "ftp://oss.sgi.com/projects/xfs/cmd_tars/${P}.tar.gz" 
> +SRC_URI[md5sum] = "049cf9873794ea49d0bb3f12d45748a4" +SRC_URI[sha256sum]
> = "e150914210ac5fd29c098ef0fd94bdec51d2fb231cf9faa765c16ec6d75c8eaa" + 
> +PARALLEL_MAKE = ""

move below inherit autotools

> +inherit autotools +EXTRA_OECONF = "--enable-gettext=no" +LIBTOOL =
> "${HOST_SYS}-libtool" +EXTRA_OEMAKE = "'LIBTOOL=${LIBTOOL}'" 
> +TARGET_CC_ARCH += "${LDFLAGS}" + +FILES_${PN}-dev +=
> "${base_libdir}/libhandle.la \ +
> ${base_libdir}/libhandle.so"

Move below do_install

> + +do_configure () { +	export DEBUG="-DNDEBUG" +	oe_runconf +} + 
> +do_install () { +	export DIST_ROOT=${D} +	oe_runmake install +	# needed
> for xfsdump +	oe_runmake install-dev +	# replace extra links to /usr/lib
> with relative links (otherwise autotools_prepackage_lamangler fails to
> read nonexistent link) +	rm -f ${D}/${base_libdir}/libhandle.la +	rm -f
> ${D}/${base_libdir}/libhandle.a +	ln -s ../usr/lib/libhandle.la
> ${D}/${base_libdir}/libhandle.la +	ln -s ../usr/lib/libhandle.a
> ${D}/${base_libdir}/libhandle.a + +	# and link from /usr/lib/libhandle.so
> to /lib/libhandle.so +	rm -f ${D}/${libdir}/libhandle.so +	ln -s
> ../../lib/libhandle.a ${D}/${libdir}/libhandle.so +} +

-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.11 (Darwin)
Comment: GPGTools - http://gpgtools.org

iEYEARECAAYFAk7q+T4ACgkQMkyGM64RGpGJBgCcDoVQ7+QAiUlcHgBtZRtU9atm
dKgAoLUGquZFtXaU9Xfy3nztzqsg3Ou6
=92fE
-----END PGP SIGNATURE-----

Patch

diff --git a/meta-oe/recipes-support/xfsprogs/xfsprogs_3.1.7.bb b/meta-oe/recipes-support/xfsprogs/xfsprogs_3.1.7.bb
new file mode 100644
index 0000000..07644ac
--- /dev/null
+++ b/meta-oe/recipes-support/xfsprogs/xfsprogs_3.1.7.bb
@@ -0,0 +1,43 @@ 
+DESCRIPTION = "XFS Filesystem Utilities"
+HOMEPAGE = "http://oss.sgi.com/projects/xfs"
+LICENSE = "GPL"
+SECTION = "base"
+DEPENDS = "util-linux"
+
+LIC_FILES_CHKSUM = "file://Makefile;endline=3;md5=def2844770bb44eba37bc9ca8610fad4"
+
+SRC_URI = "ftp://oss.sgi.com/projects/xfs/cmd_tars/${P}.tar.gz"
+SRC_URI[md5sum] = "049cf9873794ea49d0bb3f12d45748a4"
+SRC_URI[sha256sum] = "e150914210ac5fd29c098ef0fd94bdec51d2fb231cf9faa765c16ec6d75c8eaa"
+
+PARALLEL_MAKE = ""
+inherit autotools
+EXTRA_OECONF = "--enable-gettext=no"
+LIBTOOL = "${HOST_SYS}-libtool"
+EXTRA_OEMAKE = "'LIBTOOL=${LIBTOOL}'"
+TARGET_CC_ARCH += "${LDFLAGS}"
+
+FILES_${PN}-dev += "${base_libdir}/libhandle.la \
+                    ${base_libdir}/libhandle.so"
+
+do_configure () {
+	export DEBUG="-DNDEBUG"
+	oe_runconf
+}
+
+do_install () {
+	export DIST_ROOT=${D}
+	oe_runmake install
+	# needed for xfsdump
+	oe_runmake install-dev
+	# replace extra links to /usr/lib with relative links (otherwise autotools_prepackage_lamangler fails to read nonexistent link)
+	rm -f ${D}/${base_libdir}/libhandle.la
+	rm -f ${D}/${base_libdir}/libhandle.a
+	ln -s ../usr/lib/libhandle.la ${D}/${base_libdir}/libhandle.la
+	ln -s ../usr/lib/libhandle.a ${D}/${base_libdir}/libhandle.a
+
+	# and link from /usr/lib/libhandle.so to /lib/libhandle.so
+	rm -f ${D}/${libdir}/libhandle.so
+	ln -s ../../lib/libhandle.a ${D}/${libdir}/libhandle.so
+}
+