diff mbox series

[meta-gnome,PATCHv2] gnome-software: add recipe

Message ID 20221221025945.33420-1-f_l_k@t-online.de
State Under Review
Headers show
Series [meta-gnome,PATCHv2] gnome-software: add recipe | expand

Commit Message

Markus Volk Dec. 21, 2022, 2:59 a.m. UTC 
Signed-off-by: Markus Volk <f_l_k@t-online.de>
---
 .../gnome-software/gnome-software_43.2.bb     | 44 +++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 meta-gnome/recipes-gnome/gnome-software/gnome-software_43.2.bb
diff mbox series

Patch

diff --git a/meta-gnome/recipes-gnome/gnome-software/gnome-software_43.2.bb b/meta-gnome/recipes-gnome/gnome-software/gnome-software_43.2.bb
new file mode 100644
index 000000000..183a2d107
--- /dev/null
+++ b/meta-gnome/recipes-gnome/gnome-software/gnome-software_43.2.bb
@@ -0,0 +1,44 @@ 
+SUMMARY = "GNOME Software allows users to easily find, discover and install apps."
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+
+GNOMEBASEBUILDCLASS = "meson"
+GTKDOC_MESON_OPTION ?= "gtk_doc"
+
+inherit gnomebase gsettings itstool gnome-help gtk-icon-cache gtk-doc mime mime-xdg gettext upstream-version-is-even features_check
+
+REQUIRED_DISTRO_FEATURES = "x11 polkit systemd pam"
+
+DEPENDS += " \
+	appstream \
+	gdk-pixbuf \
+	glib-2.0 \
+	glib-2.0-native \
+	gsettings-desktop-schemas \
+	gtk4 \
+	iso-codes \
+	json-glib \
+	libadwaita \
+	libgudev \
+	libsoup-3.0 \
+	libxmlb-native \
+	polkit \
+"
+
+RDEPENDS:${PN} = "iso-codes"
+
+EXTRA_OEMESON += "-Dtests=false -Dsoup2=false"
+
+SRC_URI[archive.sha256sum] = "22aa7f0a317c770f68b897e9e512b2cbedb181b695ffdb0b658d99bbd64f368d"
+
+PACKAGECONFIG ?= "flatpak"
+PACKAGECONFIG[flatpak] = "-Dflatpak=true,-Dflatpak=false,flatpak ostree"
+PACKAGECONFIG[snap] = "-Dsnap=true,-Dsnap=false,snapd-glib"
+PACKAGECONFIG[gtk_doc] = "-Dgtk_doc=true,-Dgtk_doc=false,libxslt-native docbook-xsl-stylesheets"
+PACKAGECONFIG[man] = "-Dman=true,-Dman=false,libxslt-native docbook-xsl-stylesheets"
+PACKAGECONFIG[packagekit] = "-Dpackagekit=true,-Dpackagekit=false,gnome-packagekit,gnome-packagekit"
+PACKAGECONFIG[fwupd] = "-Dfwupd=true,-Dfwupd=false,fwupd,fwupd"
+PACKAGECONFIG[malcontent] = "-Dmalcontent=true,-Dmalcontent=false,malcontent"
+
+FILES:${PN} += "${datadir}"
+FILES:${PN}-dev += "${libdir}/gnome-software/libgnomesoftware.so"